***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 26, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   P-unit   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = -0.75		 kp = 10.3		   rb = 2.545e-2)
.model  dds   d(
+   is = 8.644e-13	  n = 1.122e0		   rs = 9.526e-2		ikf = 4.842e-2
+   eg = 1.152e0       trs1 = -1.292e-3 )
.model  dbody d(
+   is = 9.644e-13	  n = 1.122e0		   rs = 9.526e-2		ikf = 4.842e-2
+   eg = 1.152e0       trs1 = -1.292e-3
+  cjo = 2.498e-9	  m = 1.078		   vj = 2.631
+   bv = 22		ibv = 250e-6		 tbv1 = 4.253e-4		 tt = 25n)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 7.358e-10	  m = 3.192		   vj = 8.336)
.param
+  cgs = 8.303e-10	cgd = 1.540e-10
+   rd = 2.367e-2	 ra = 2.033e-2		 trd1 = 5.349e-3
*****function & circuit***
rg	 G   1t   1
cgs	 1t   3   {cgs}
egv	 3   2t   table   {v(S, 1t)}
+((0.00 , 0.00 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.50 ),
+ (2.00 , 2.00 ),
+ (2.25 , 2.20 ),
+ (2.50 , 2.38 ),
+ (2.75 , 2.55 ),
+ (3.00 , 2.68 ),
+ (4.00 , 3.10 ),
+ (4.50 , 3.25 ),
+ (6.00 , 3.52 ),
+ (8.00 , 3.78 ),
+ (10.0 , 4.02 ),
+ (12.0 , 4.05 ),
+ (14.0 , 4.05 ))
egt	  1  2t   value = {6.021e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1     1t   8   6   6   inter
e1      8   6   4  1t   2
cgd	  7   4   {cgd}
rcgd    7   4   10meg
dgd     4   6   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends
*$
.subckt   N-unit   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = .78		 kp = 13.82		   rb = 5e-2)
.model  dds   d(
+   is = 2.087e-11	  n = 1.208		   rs = 5.002e-2		 ikf = 9.338e-1
+   eg = 1.052	       trs1 = 1.378e-4 )
.model  dbody d(
+   is = 9.087e-12	  n = 1.208		   rs = 5.002e-2		 ikf = 9.338e-1
+   eg = 1.052	       trs1 = 1.378e-4
+  cjo = 2.635e-11	  m = 1.890e-1		   vj = 7.487e-2
+   bv = 22		ibv = 250e-6		 tbv1 = 1.505e-3		tbv2 = -6.855e-6
+   tt = 25n)
.model  inter  nmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 2.042e-10	  m = 4.844e-1		   vj = 1.544e-1)
.param
+  cgs = 5.329e-10	cgd = 3.291e-10
+   rd = 5.280e-3	 ra = 5.720e-3		 trd1 = 1.035e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	 2t   3   table   {v(1t, S)}
+((0.00 , 0.00 ),
+ (0.50 , 0.55 ),
+ (1.00 , 1.09 ),
+ (1.50 , 1.62 ),
+ (2.00 , 2.10 ),
+ (2.50 , 2.50 ),
+ (3.00 , 3.00 ),
+ (4.00 , 3.35 ),
+ (5.00 , 3.52 ),
+ (7.00 , 3.72 ),
+ (8.00 , 3.76 ),
+ (10.0 , 3.82 ),
+ (12.0 , 3.82 ))
egt	  1  2t   value = {5.987e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4  1t   2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       6   4   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
